PowerPointVBATips/アドインが読み込まれた時にツールバーを表示する - Power Point Tools Wiki - Power Point Tools

* PowerPointVBATips:アドインが読み込まれた時にツールバーを表示する

アドインが読み込まれた時にアドイン独自のツールバーを表示するようにするには、Sub Auto_Open()をモジュールに追加し、ツールバーを作成するコードを書きます。trimmer.ppaのソースを例に説明します。

まず、モジュールの宣言部でツールバーやその上に置くアイコンの名前を定数宣言しておきます。他のモジュールからアクセスできない様にPrivateにしておきましょう。

 Private Const TOOL_BAR As String = "RedAddins"
 Private Const DEL_ANIME As String = "アニメーション全削除"
 (以下、略)

次にAuto_Openプロシージャでツールバーを作成します。

  Sub Auto_Open()
     Dim cbrWiz       As CommandBar
     Dim ctlInsert    As CommandBarButton
  
     On Error Resume Next
     ' コマンド バーが既に存在するかどうかを確認します。
     Set cbrWiz = CommandBars(TOOL_BAR)
     ' コマンド バーが存在しない場合は作成します。
     If cbrWiz Is Nothing Then
        Err.Clear
        Set cbrWiz = CommandBars.Add(TOOL_BAR, msoBarTop) ' ツールバーを作成
        ' コマンド バーを表示
        cbrWiz.Visible = True
  
        Set ctlInsert = cbrWiz.Controls.Add 'ツールバーにコントロールを追加。
        With ctlInsert
           .Style = msoButtonCaption　' 表示のスタイル(この場合、キャプション表示)
           .Caption = CR_FIT
           .Tag = CR_FIT
           .OnAction = "CropFitToSlide" ' 押された時に実行するサブプロシージャ
        End With
  
        (中略)
  
     End If
  End Sub

なお、モジュールがアンロードされるときには、ツールバーを削除する方が良いでしょう。次の様なサブプロシージャを追加します。

  Sub Auto_Close()
     On Error Resume Next
     ' 存在するコマンド バーを削除します。
     CommandBars(TOOL_BAR).Delete
  End Sub